add missing BLAS/LAPACK functions used by LATTE to linalg lib
This commit is contained in:
Axel Kohlmeyer
314
lib/linalg/dsygv.f
Normal file
314
lib/linalg/dsygv.f
Normal file
@ -0,0 +1,314 @@
|
||||
*> \brief \b DSYGST
|
||||
*
|
||||
* =========== DOCUMENTATION ===========
|
||||
*
|
||||
* Online html documentation available at
|
||||
* http://www.netlib.org/lapack/explore-html/
|
||||
*
|
||||
*> \htmlonly
|
||||
*> Download DSYGV + dependencies
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/dsygv.f">
|
||||
*> [TGZ]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/dsygv.f">
|
||||
*> [ZIP]</a>
|
||||
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/dsygv.f">
|
||||
*> [TXT]</a>
|
||||
*> \endhtmlonly
|
||||
*
|
||||
* Definition:
|
||||
* ===========
|
||||
*
|
||||
* SUBROUTINE DSYGV( ITYPE, JOBZ, UPLO, N, A, LDA, B, LDB, W, WORK,
|
||||
* LWORK, INFO )
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
* CHARACTER JOBZ, UPLO
|
||||
* INTEGER INFO, ITYPE, LDA, LDB, LWORK, N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
* DOUBLE PRECISION A( LDA, * ), B( LDB, * ), W( * ), WORK( * )
|
||||
* ..
|
||||
*
|
||||
*
|
||||
*> \par Purpose:
|
||||
* =============
|
||||
*>
|
||||
*> \verbatim
|
||||
*>
|
||||
*> DSYGV computes all the eigenvalues, and optionally, the eigenvectors
|
||||
*> of a real generalized symmetric-definite eigenproblem, of the form
|
||||
*> A*x=(lambda)*B*x, A*Bx=(lambda)*x, or B*A*x=(lambda)*x.
|
||||
*> Here A and B are assumed to be symmetric and B is also
|
||||
*> positive definite.
|
||||
*> \endverbatim
|
||||
*
|
||||
* Arguments:
|
||||
* ==========
|
||||
*
|
||||
*> \param[in] ITYPE
|
||||
*> \verbatim
|
||||
*> ITYPE is INTEGER
|
||||
*> Specifies the problem type to be solved:
|
||||
*> = 1: A*x = (lambda)*B*x
|
||||
*> = 2: A*B*x = (lambda)*x
|
||||
*> = 3: B*A*x = (lambda)*x
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] JOBZ
|
||||
*> \verbatim
|
||||
*> JOBZ is CHARACTER*1
|
||||
*> = 'N': Compute eigenvalues only;
|
||||
*> = 'V': Compute eigenvalues and eigenvectors.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] UPLO
|
||||
*> \verbatim
|
||||
*> UPLO is CHARACTER*1
|
||||
*> = 'U': Upper triangles of A and B are stored;
|
||||
*> = 'L': Lower triangles of A and B are stored.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] N
|
||||
*> \verbatim
|
||||
*> N is INTEGER
|
||||
*> The order of the matrices A and B. N >= 0.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in,out] A
|
||||
*> \verbatim
|
||||
*> A is DOUBLE PRECISION array, dimension (LDA, N)
|
||||
*> On entry, the symmetric matrix A. If UPLO = 'U', the
|
||||
*> leading N-by-N upper triangular part of A contains the
|
||||
*> upper triangular part of the matrix A. If UPLO = 'L',
|
||||
*> the leading N-by-N lower triangular part of A contains
|
||||
*> the lower triangular part of the matrix A.
|
||||
*>
|
||||
*> On exit, if JOBZ = 'V', then if INFO = 0, A contains the
|
||||
*> matrix Z of eigenvectors. The eigenvectors are normalized
|
||||
*> as follows:
|
||||
*> if ITYPE = 1 or 2, Z**T*B*Z = I;
|
||||
*> if ITYPE = 3, Z**T*inv(B)*Z = I.
|
||||
*> If JOBZ = 'N', then on exit the upper triangle (if UPLO='U')
|
||||
*> or the lower triangle (if UPLO='L') of A, including the
|
||||
*> diagonal, is destroyed.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LDA
|
||||
*> \verbatim
|
||||
*> LDA is INTEGER
|
||||
*> The leading dimension of the array A. LDA >= max(1,N).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in,out] B
|
||||
*> \verbatim
|
||||
*> B is DOUBLE PRECISION array, dimension (LDB, N)
|
||||
*> On entry, the symmetric positive definite matrix B.
|
||||
*> If UPLO = 'U', the leading N-by-N upper triangular part of B
|
||||
*> contains the upper triangular part of the matrix B.
|
||||
*> If UPLO = 'L', the leading N-by-N lower triangular part of B
|
||||
*> contains the lower triangular part of the matrix B.
|
||||
*>
|
||||
*> On exit, if INFO <= N, the part of B containing the matrix is
|
||||
*> overwritten by the triangular factor U or L from the Cholesky
|
||||
*> factorization B = U**T*U or B = L*L**T.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LDB
|
||||
*> \verbatim
|
||||
*> LDB is INTEGER
|
||||
*> The leading dimension of the array B. LDB >= max(1,N).
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] W
|
||||
*> \verbatim
|
||||
*> W is DOUBLE PRECISION array, dimension (N)
|
||||
*> If INFO = 0, the eigenvalues in ascending order.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] WORK
|
||||
*> \verbatim
|
||||
*> WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK))
|
||||
*> On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[in] LWORK
|
||||
*> \verbatim
|
||||
*> LWORK is INTEGER
|
||||
*> The length of the array WORK. LWORK >= max(1,3*N-1).
|
||||
*> For optimal efficiency, LWORK >= (NB+2)*N,
|
||||
*> where NB is the blocksize for DSYTRD returned by ILAENV.
|
||||
*>
|
||||
*> If LWORK = -1, then a workspace query is assumed; the routine
|
||||
*> only calculates the optimal size of the WORK array, returns
|
||||
*> this value as the first entry of the WORK array, and no error
|
||||
*> message related to LWORK is issued by XERBLA.
|
||||
*> \endverbatim
|
||||
*>
|
||||
*> \param[out] INFO
|
||||
*> \verbatim
|
||||
*> INFO is INTEGER
|
||||
*> = 0: successful exit
|
||||
*> < 0: if INFO = -i, the i-th argument had an illegal value
|
||||
*> > 0: DPOTRF or DSYEV returned an error code:
|
||||
*> <= N: if INFO = i, DSYEV failed to converge;
|
||||
*> i off-diagonal elements of an intermediate
|
||||
*> tridiagonal form did not converge to zero;
|
||||
*> > N: if INFO = N + i, for 1 <= i <= N, then the leading
|
||||
*> minor of order i of B is not positive definite.
|
||||
*> The factorization of B could not be completed and
|
||||
*> no eigenvalues or eigenvectors were computed.
|
||||
*> \endverbatim
|
||||
*
|
||||
* Authors:
|
||||
* ========
|
||||
*
|
||||
*> \author Univ. of Tennessee
|
||||
*> \author Univ. of California Berkeley
|
||||
*> \author Univ. of Colorado Denver
|
||||
*> \author NAG Ltd.
|
||||
*
|
||||
*> \date November 2011
|
||||
*
|
||||
*> \ingroup doubleSYeigen
|
||||
*
|
||||
* =====================================================================
|
||||
SUBROUTINE DSYGV( ITYPE, JOBZ, UPLO, N, A, LDA, B, LDB, W, WORK,
|
||||
$ LWORK, INFO )
|
||||
*
|
||||
* -- LAPACK driver routine (version 3.4.0) --
|
||||
* -- LAPACK is a software package provided by Univ. of Tennessee, --
|
||||
* -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
|
||||
* November 2011
|
||||
*
|
||||
* .. Scalar Arguments ..
|
||||
CHARACTER JOBZ, UPLO
|
||||
INTEGER INFO, ITYPE, LDA, LDB, LWORK, N
|
||||
* ..
|
||||
* .. Array Arguments ..
|
||||
DOUBLE PRECISION A( LDA, * ), B( LDB, * ), W( * ), WORK( * )
|
||||
* ..
|
||||
*
|
||||
* =====================================================================
|
||||
*
|
||||
* .. Parameters ..
|
||||
DOUBLE PRECISION ONE
|
||||
PARAMETER ( ONE = 1.0D+0 )
|
||||
* ..
|
||||
* .. Local Scalars ..
|
||||
LOGICAL LQUERY, UPPER, WANTZ
|
||||
CHARACTER TRANS
|
||||
INTEGER LWKMIN, LWKOPT, NB, NEIG
|
||||
* ..
|
||||
* .. External Functions ..
|
||||
LOGICAL LSAME
|
||||
INTEGER ILAENV
|
||||
EXTERNAL LSAME, ILAENV
|
||||
* ..
|
||||
* .. External Subroutines ..
|
||||
EXTERNAL DPOTRF, DSYEV, DSYGST, DTRMM, DTRSM, XERBLA
|
||||
* ..
|
||||
* .. Intrinsic Functions ..
|
||||
INTRINSIC MAX
|
||||
* ..
|
||||
* .. Executable Statements ..
|
||||
*
|
||||
* Test the input parameters.
|
||||
*
|
||||
WANTZ = LSAME( JOBZ, 'V' )
|
||||
UPPER = LSAME( UPLO, 'U' )
|
||||
LQUERY = ( LWORK.EQ.-1 )
|
||||
*
|
||||
INFO = 0
|
||||
IF( ITYPE.LT.1 .OR. ITYPE.GT.3 ) THEN
|
||||
INFO = -1
|
||||
ELSE IF( .NOT.( WANTZ .OR. LSAME( JOBZ, 'N' ) ) ) THEN
|
||||
INFO = -2
|
||||
ELSE IF( .NOT.( UPPER .OR. LSAME( UPLO, 'L' ) ) ) THEN
|
||||
INFO = -3
|
||||
ELSE IF( N.LT.0 ) THEN
|
||||
INFO = -4
|
||||
ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
|
||||
INFO = -6
|
||||
ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
|
||||
INFO = -8
|
||||
END IF
|
||||
*
|
||||
IF( INFO.EQ.0 ) THEN
|
||||
LWKMIN = MAX( 1, 3*N - 1 )
|
||||
NB = ILAENV( 1, 'DSYTRD', UPLO, N, -1, -1, -1 )
|
||||
LWKOPT = MAX( LWKMIN, ( NB + 2 )*N )
|
||||
WORK( 1 ) = LWKOPT
|
||||
*
|
||||
IF( LWORK.LT.LWKMIN .AND. .NOT.LQUERY ) THEN
|
||||
INFO = -11
|
||||
END IF
|
||||
END IF
|
||||
*
|
||||
IF( INFO.NE.0 ) THEN
|
||||
CALL XERBLA( 'DSYGV ', -INFO )
|
||||
RETURN
|
||||
ELSE IF( LQUERY ) THEN
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
* Quick return if possible
|
||||
*
|
||||
IF( N.EQ.0 )
|
||||
$ RETURN
|
||||
*
|
||||
* Form a Cholesky factorization of B.
|
||||
*
|
||||
CALL DPOTRF( UPLO, N, B, LDB, INFO )
|
||||
IF( INFO.NE.0 ) THEN
|
||||
INFO = N + INFO
|
||||
RETURN
|
||||
END IF
|
||||
*
|
||||
* Transform problem to standard eigenvalue problem and solve.
|
||||
*
|
||||
CALL DSYGST( ITYPE, UPLO, N, A, LDA, B, LDB, INFO )
|
||||
CALL DSYEV( JOBZ, UPLO, N, A, LDA, W, WORK, LWORK, INFO )
|
||||
*
|
||||
IF( WANTZ ) THEN
|
||||
*
|
||||
* Backtransform eigenvectors to the original problem.
|
||||
*
|
||||
NEIG = N
|
||||
IF( INFO.GT.0 )
|
||||
$ NEIG = INFO - 1
|
||||
IF( ITYPE.EQ.1 .OR. ITYPE.EQ.2 ) THEN
|
||||
*
|
||||
* For A*x=(lambda)*B*x and A*B*x=(lambda)*x;
|
||||
* backtransform eigenvectors: x = inv(L)**T*y or inv(U)*y
|
||||
*
|
||||
IF( UPPER ) THEN
|
||||
TRANS = 'N'
|
||||
ELSE
|
||||
TRANS = 'T'
|
||||
END IF
|
||||
*
|
||||
CALL DTRSM( 'Left', UPLO, TRANS, 'Non-unit', N, NEIG, ONE,
|
||||
$ B, LDB, A, LDA )
|
||||
*
|
||||
ELSE IF( ITYPE.EQ.3 ) THEN
|
||||
*
|
||||
* For B*A*x=(lambda)*x;
|
||||
* backtransform eigenvectors: x = L*y or U**T*y
|
||||
*
|
||||
IF( UPPER ) THEN
|
||||
TRANS = 'T'
|
||||
ELSE
|
||||
TRANS = 'N'
|
||||
END IF
|
||||
*
|
||||
CALL DTRMM( 'Left', UPLO, TRANS, 'Non-unit', N, NEIG, ONE,
|
||||
$ B, LDB, A, LDA )
|
||||
END IF
|
||||
END IF
|
||||
*
|
||||
WORK( 1 ) = LWKOPT
|
||||
RETURN
|
||||
*
|
||||
* End of DSYGV
|
||||
*
|
||||
END
|
||||
Reference in New Issue
Block a user