#!/usr/bin/gnuplot

set terminal postscript eps monochrome
set output "numberDensity.eps"
set decimalsign "."

set format xy '%g'
set xtics 1 mirror
set xlabel 'v(m^3)'
set ytics 0.005 mirror
set ylabel 'n(m^{-3}m^{-3})'

set xrange [1:15]
set yrange [0:1.5e-2]
set key top right

plot "<printf '2 0\n2 0.01\n4 0.01\n4 0\n'" w l t 'Initial Condition',\
"<printf '8 0\n8 0.01\n10 0.01\n10 0\n'" w l t '[Kumar J., PhD thesis, Magdeburg, 2006]',\
'numberDensity.transposed.dat' u 1:2 w lp t 'air'

set output "moments.eps"

set format xy '%g'
set xlabel 't(s)'
set ytics 0.5 mirror
set ylabel 'M_j(t)/M_j(t=0)'

set xrange [0:6]
set yrange [0.5:3.5]
set key top left

plot 'postProcessing/moments/0/moments.dat' u 1:($2/0.024535) w p pt 5 t 'j=0 (Numbers), air',\
"<printf '0 1\n6 1\n'" w l t 'j=0 (Numbers), [Kumar J., PhD thesis, Magdeburg, 2006]',\
'postProcessing/moments/0/moments.dat' u 1:($3/0.0751237) w p pt 6 t 'j=1 (Volume), air',\
"<printf '0 1\n6 3\n'" w l t 'j=1 (Volume), [Kumar J., PhD thesis, Magdeburg, 2006]'